David Behan's Blog » ASP/SQL/JS Code

ASP: NON-WWW 301 Redirect on IIS

David — Tue, 29 May 2007 07:44:03 +0000

I was doing some research on how to do a non-www 301 redirect on a Windows IIS server and I found the usual response.status and response.addheader solution, which also required access to IIS for spliting up the www and non-www part of your domain. If you are on a shared server, this isn’t always possible. I wanted a pure code version of the redirect that I could drop into my pages so that if somebody visited a page on the site that had sub folders and/or querystrings without the www part, it would preserve these and redirect to the www version. I couldn’t find exactly what I was looking for so I decided to write my own in ASP.

The script below should be inserted into the top of all the pages you want this to work. The best way to do this is using an include file or adding it to the top of one of your existing include files that runs before anything is written to the page. The pages also need to be ASP. This will not work on plain html pages. This isn’t a perfect solution as it will only work on actual pages but it will help a lot of people out there I think. On linux, this is much easier using the htaccess solution but as IIS doesn’t have this, this is a good alternative. If www exists in the URL, this script will not execute. You may want to do the same in reverse, as in redirect www to non-www URL’s. If there is a demand for this, I’ll modify the script to support it.

You can see a working example of this by trying to visit http://davidbehan.com/?test=ok. It should redirect to http://www.davidbehan.com/?test=ok.

‘Collect url information being requested
svrHttps = request.servervariables("HTTPS")
svrHost = request.servervariables("HTTP_HOST")
svrUrl = request.servervariables("URL")
svrQueryString = request.servervariables("QUERY_STRING")

‘Check if www appears in the domain and begin building url to redirect to if it doesn’t
IF left(svrHost,4) <> "www." THEN

‘Check if the page is secure or not
IF svrHttps = "off" THEN

svrNewUrl = "http://www."

ELSE

svrNewUrl = "https://www."

END IF

‘Add the domain, folder(s) and page requested as well as remove directory indexes
svrNewUrl = svrNewUrl & svrHost & svrUrl
svrNewUrl = replace(svrNewUrl,"default.asp","")
svrNewUrl = replace(svrNewUrl,"index.asp","")

‘If there is a querystring, add it to the redirect link
IF len(svrQueryString) > 0 THEN

svrNewUrl = svrNewUrl & "?" & svrQueryString

END IF

‘Do the actual 301 redirect to the newly constructed url
response.status = "301 Moved Permanently"
response.addheader "Location", svrNewUrl
response.end

END IF

Test in IE7 and IE6 using VPC on the same machine

David — Mon, 04 Dec 2006 14:13:41 +0000

Ok, IE7 was released recently and for a lot of designers/developers out there it means having to use two machines to do the testing or using hacks (that don’t work 100%). Microsoft have just released a FREE Virtual PC containing a pre-activated Windows XP SP2, with IE6 and the IE7 Readiness Toolkit to allow you to easily test in both IE6 and IE7 on the same machine.

Read about the release at the IEBlog or download it.

ASP Send E-Mail Function

David — Fri, 27 Oct 2006 16:44:57 +0000

This neat little ASP send mail function can be included and called to quickly send e-mails using CDONTS, CDOSYS, ASPMail, ASPEmail, Dundas Mailer or Jmail. All you need to do is copy the code below into a file, say sendmail.asp and include that file in any page you want to send a mail in.

Copy the following lines of code into sendmail.asp:

< %
'--------------------------------------
'Notes - Read Me!
'--------------------------------------
'sToName - can be any type of text string, e.g. Joe Bloggs
'sToAddress - must be a valid email address as this is the email address the mail will be sent, e.g. joe@bloggs.com
'sFromName - can be any type of text string, e.g. Mary Bloggs
'sFromAddress - must be a valid email address as this is the email address the mail will come from, e.g. mary@bloggs.com
'sSubject - can be any type of text string, e.g. July Newsletter
'sContent - this is the actual body content of the email. can be html or just text, just make sure you have set the correct mail body settings
'sFormat - enter 'html' or 'text'
'sImportance - enter 'high', 'normal' or 'low'

sComponent = "jmail" 'can be cdonts, cdosys, aspmail, aspemail, dundas, jmail
sMailServer = "mail.yourdomain.com"

FUNCTION SendMail(sToName, sToAddress, sFromName, sFromAddress, sSubject, sContent, sFormat, sImportance)

SELECT CASE sComponent

'-------------------------------
'CDONTS - www.microsoft.com
'-------------------------------
CASE "cdonts"

SET objMail = Server.CreateObject("CDONTS.NewMail")

IF sFormat = "text" THEN
objMail.BodyFormat = 1
objMail.MailFormat = 1
ELSE
objMail.BodyFormat = 0
objMail.MailFormat = 0
END IF

IF sImportance = "high" THEN
objMail.Importance = 2
ELSEIF sImportance = "low" THEN
objMail.Importance = 0
ELSE
objMail.Importance = 1
END IF

objMail.From = sFromName & "<" & sFromAddress & ">"
objMail.To = sToName & "< " & sToAddress & ">"
objMail.Subject = sSubject
objMail.Body = sContent
objMail.Send

'-------------------------------
'CDONTS - www.microsoft.com
'-------------------------------
CASE "cdosys"

SET objMail = Server.CreateObject("CDO.Message")
Set objConfig = Server.CreateObject ("CDO.Configuration")

objConfig.Fields ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = sMailServer 'change this to your websites mail domain
objConfig.Fields ("http://schemas.microsoft.com/cdo/configuration/smtpserverport")  = 25
objConfig.Fields ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objConfig.Fields ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
Set objMail.Configuration = objConfig

IF sFormat = "text" THEN
objMail.TextBody = sContent
ELSE
objMail.HtmlBody = sContent
END IF

IF sImportance = "high" THEN
objMail.Fields ("urn:schemas:httpmail:importance").Value = 2
objMail.Fields.Update()
ELSEIF sImportance = "low" THEN
objMail.Fields ("urn:schemas:httpmail:importance").Value = 0
objMail.Fields.Update()
ELSE
objMail.Fields ("urn:schemas:httpmail:importance").Value = 1
objMail.Fields.Update()
END IF

objMail.From = sFromName & "< " & sFromAddress & ">"
objMail.To = sToName & "< " & sToAddress & ">"
objMail.Subject = sSubject
objMail.Send

Set objMail = Nothing
Set objConfig = Nothing

'-------------------------------
'ASPMail - www.serverobjects.com
'-------------------------------
CASE "aspmail"

SET objMail = Server.CreateObject("SMTPsvg.Mailer")

IF sFormat = "text" THEN
objMail.CharSet = 2
Else
objMail.ContentType = "text/html"
End If

If sImportance = "high" Then
objMail.Priority = 1
ElseIf sImportance = "low" Then
objMail.Priority = 5
Else
objMail.Priority = 3
End If

objMail.FromName = sFromName
objMail.FromAddress= sFromAddress
objMail.RemoteHost = sMailServer
objMail.Subject = sSubject
objMail.BodyText = sContent
objMail.AddRecipient sToAddress, sToName
objMail.SendMail

'-------------------------------
'ASPEmail - www.aspemail.com
'-------------------------------
Case "aspemail"

Set objMail = Server.CreateObject("Persits.MailSender")

If sFormat = "text" Then
objMail.Ishtml = False
Else
objMail.Ishtml = True
End If

If sImportance = "high" Then
objMail.Priority = 1
ElseIf sImportance = "low" Then
objMail.Priority = 5
Else
objMail.Priority = 3
End If

objMail.Host = sMailServer
objMail.From = sFromAddress
objMail.FromName = sFromName
objMail.AddAddress sToAddress, sToName
objMail.Subject = sSubject
objMail.Body = sContent
objMail.Send

'-------------------------------
'JMail - www.dimac.net
'-------------------------------
Case "jmail"

set objMail = Server.CreateOBject("JMail.Message")

If sImportance = "high" Then
objMail.Priority = 1
ElseIf sImportance = "low" Then
objMail.Priority = 5
Else
objMail.Priority = 3
End If

If sFormat = "text" Then
objMail.body = sContent
Else
objMail.HTMLBody = sContent
END IF

objMail.Logging = true
objMail.silent = true
objMail.From = sFromAddress
objMail.FromName = sFromName
objMail.AddRecipient sToAddress, sToName
objMail.Subject = sSubject
objMail.Send(sMailServer)

'-------------------------------
'Dundas - www.dundas.com
'-------------------------------
Case "dundas"

set objMail = Server.CreateOBject("Dundas.Mailer")

If sImportance = "high" Then
objMail.Priority = 1
ElseIf sImportance = "low" Then
objMail.Priority = 5
Else
objMail.Priority = 3
End If

If sFormat = "text" Then
objMail.body = sContent
Else
objMail.htmlBody = sContent
End If

objMail.FromAddress = sFromAddress
objMail.FromName = sFromName
objMail.TOs.Add sToAddress, sToName
objMail.Subject = sSubject
objMail.SMTPRelayServers.Add sMailServer
objMail.SendMail

End Select

END FUNCTION
%>

To send the mail, include sendmail.asp and use the following lines of code:

CALL SendMail("Joe Bloggs","joe@bloggs.com","Jane Bloggs","jane@bloggs.com","Test Email","Test Content","html","high")